apply plugin: 'com.android.application'

android {
    compileSdkVersion rootProject.ext.android.compileSdkVersion

    defaultConfig {
        applicationId "com.mogo.cloud"
        minSdkVersion rootProject.ext.android.minSdkVersion
        targetSdkVersion rootProject.ext.android.targetSdkVersion
        versionCode 1
        versionName "1.0"

        multiDexEnabled true
        packagingOptions {
            //解决编译时com.android.builder.merge.DuplicateRelativeFileException: More than one file was found with OS independent path 'META-INF/rxjava.properties'这个错误
            exclude 'META-INF/rxjava.properties'
            exclude 'META-INF/DEPENDENCIES'
        }

        ndk {
            abiFilters "armeabi-v7a", "arm64-v8a"//, "armeabi"
        }
    }

    sourceSets {
        main {
            jniLibs.srcDirs = ['libs']
            jni.srcDirs = []
        }
    }

    buildTypes {
        debug {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }
    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }
}

dependencies {
    implementation fileTree(dir: "libs", include: ["*.jar"])
    implementation 'com.android.support:multidex:1.0.3'

    implementation rootProject.ext.dependencies.androidxappcompat
    implementation rootProject.ext.dependencies.crashSdk
    implementation rootProject.ext.dependencies.androidxconstraintlayout
    implementation rootProject.ext.dependencies.rxjava
    implementation rootProject.ext.dependencies.rxandroid
    // 从车机获取视频流
    implementation 'com.zhidao.carmanager:common:1.0.25@aar'
    implementation 'com.google.android.material:material:1.3.0'
    implementation project(path: ':foudations:mogo-passport')

    if (Boolean.valueOf(RELEASE)) {
        implementation "com.mogo.cloud:location:${MOGO_LOCATION_VERSION}"
        implementation "com.mogo.cloud:tanlu:${MOGO_TANLU_VERSION}"
        implementation "com.mogo.cloud:realtime:${MOGO_REALTIME_VERSION}"
        implementation "com.mogo.cloud:trafficlive:${MOGO_TRAFFICLIVE_VERSION}"
        implementation "com.mogo.cloud:telematic:${MOGO_TELEMATIC_VERSION}"
        implementation "com.mogo.v2x:v2x:${MOGO_V2X_VERSION}"
    } else {
        implementation project(":foudations:mogo-location")
        implementation project(":modules:mogo-tanlu")
        implementation project(":modules:mogo-realtime")
        implementation project(":modules:mogo-trafficlive")
        implementation project(":libraries:mogo-telematic")
        implementation project(":foudations:mogo-v2x")
    }

    annotationProcessor 'com.elegant.spi:compiler:1.0.3'   //编译时库
}